ac = array[char]
ai = array[int]
ar = array[real]
ap = sequence[proctype(real,real) returns(real)
              signals(overflow,underflow,zero_divide)]

start_up = proc()
  op:ap := ap$[real$add,real$sub,real$mul,real$div]
  ous:stream := stream$primary_output()
  rs:ar := ar$new()
  skip:bool := false
  for s:string in getword() do
    x,y:real
    if skip then exit error
    elseif string$empty(s) then
      if 1<ar$size(rs) then exit error
      elseif ~ar$empty(rs) then
        y := ar$remh(rs)
        stream$putl(ous,real$unparse(y))
      end
    else
      x := real$parse(s)
      except when bad_format:
        if 1=string$size(s) then
          y,x := ar$remh(rs),ar$remh(rs)
          x := op[string$indexc(s[1],"+-*/")](x,y)
        else exit error end
      end
      ar$addh(rs,x)
    end
    except when error,bounds,overflow,underflow,zero_divide:
      skip := ~string$empty(s)
      if ~skip then
        stream$putl(ous,"error")
        ar$trim(rs,1,0)
      end
    end
  end
end start_up

getword = iter() yields (string)
  ins:stream := stream$primary_input()
  cs:ac := ac$new()
  w:string  c:char := ' '
  while true do
    while c=' ' cor c='\t' do
      c := stream$getc(ins)
    end
    if c='\n' then c := ' ' end
    while 0=string$indexc(c," \t\n") do
      ac$addh(cs,c)
      c := stream$getc(ins)
    end
    w := string$ac2s(cs)
    yield (w)
    ac$trim(cs,1,0)
  end
  except when end_of_file: end
end getword